Current Dir: /snap/core22/2437/usr/lib/x86_64-linux-gnu/perl-base/

[DIR]  auto [ delete | rename ]
[DIR]  Carp [ delete | rename ]
[DIR]  Exporter [ delete | rename ]
[DIR]  File [ delete | rename ]
[DIR]  Getopt [ delete | rename ]
[DIR]  Hash [ delete | rename ]
[DIR]  IO [ delete | rename ]
[DIR]  IPC [ delete | rename ]
[DIR]  List [ delete | rename ]
[DIR]  Scalar [ delete | rename ]
[DIR]  Text [ delete | rename ]
[DIR]  Tie [ delete | rename ]
[DIR]  unicore [ delete | rename ]
[DIR]  warnings [ delete | rename ]
[FILE] attributes.pm [ edit | delete | rename ]
[FILE] AutoLoader.pm [ edit | delete | rename ]
[FILE] base.pm [ edit | delete | rename ]
[FILE] bytes.pm [ edit | delete | rename ]
[FILE] bytes_heavy.pl [ edit | delete | rename ]
[FILE] Carp.pm [ edit | delete | rename ]
[FILE] Config.pm [ edit | delete | rename ]
[FILE] Config_git.pl [ edit | delete | rename ]
[FILE] Config_heavy.pl [ edit | delete | rename ]
[FILE] constant.pm [ edit | delete | rename ]
[FILE] Cwd.pm [ edit | delete | rename ]
[FILE] DynaLoader.pm [ edit | delete | rename ]
[FILE] Errno.pm [ edit | delete | rename ]
[FILE] Exporter.pm [ edit | delete | rename ]
[FILE] Fcntl.pm [ edit | delete | rename ]
[FILE] feature.pm [ edit | delete | rename ]
[FILE] fields.pm [ edit | delete | rename ]
[FILE] FileHandle.pm [ edit | delete | rename ]
[FILE] integer.pm [ edit | delete | rename ]
[FILE] IO.pm [ edit | delete | rename ]
[FILE] lib.pm [ edit | delete | rename ]
[FILE] locale.pm [ edit | delete | rename ]
[FILE] overload.pm [ edit | delete | rename ]
[FILE] overloading.pm [ edit | delete | rename ]
[FILE] parent.pm [ edit | delete | rename ]
[FILE] POSIX.pm [ edit | delete | rename ]
[FILE] re.pm [ edit | delete | rename ]
[FILE] SelectSaver.pm [ edit | delete | rename ]
[FILE] Socket.pm [ edit | delete | rename ]
[FILE] strict.pm [ edit | delete | rename ]
[FILE] Symbol.pm [ edit | delete | rename ]
[FILE] utf8.pm [ edit | delete | rename ]
[FILE] vars.pm [ edit | delete | rename ]
[FILE] warnings.pm [ edit | delete | rename ]
[FILE] XSLoader.pm [ edit | delete | rename ]

Viewing: /snap/core22/2437/usr/lib/x86_64-linux-gnu/perl-base/lib.pm

package lib;

# THIS FILE IS AUTOMATICALLY GENERATED FROM lib_pm.PL.
# ANY CHANGES TO THIS FILE WILL BE OVERWRITTEN BY THE NEXT PERL BUILD.

use Config;

use strict;

my $archname         = $Config{archname};
my $version          = $Config{version};
my @inc_version_list = reverse split / /, $Config{inc_version_list};

our @ORIG_INC = @INC;	# take a handy copy of 'original' value
our $VERSION = '0.65';

sub import {
    shift;

    my %names;
    foreach (reverse @_) {
	my $path = $_;		# we'll be modifying it, so break the alias
	if ($path eq '') {
	    require Carp;
	    Carp::carp("Empty compile time value given to use lib");
	}

	if ($path !~ /\.par$/i && -e $path && ! -d _) {
	    require Carp;
	    Carp::carp("Parameter to use lib must be directory, not file");
	}
	unshift(@INC, $path);
	# Add any previous version directories we found at configure time
	foreach my $incver (@inc_version_list)
	{
	    my $dir = "$path/$incver";
	    unshift(@INC, $dir) if -d $dir;
	}
	# Put a corresponding archlib directory in front of $path if it
	# looks like $path has an archlib directory below it.
	my($arch_auto_dir, $arch_dir, $version_dir, $version_arch_dir)
	    = _get_dirs($path);
	unshift(@INC, $arch_dir)         if -d $arch_auto_dir;
	unshift(@INC, $version_dir)      if -d $version_dir;
	unshift(@INC, $version_arch_dir) if -d $version_arch_dir;
    }

    # remove trailing duplicates
    @INC = grep { ++$names{$_} == 1 } @INC;
    return;
}

sub unimport {
    shift;

    my %names;
    foreach my $path (@_) {
	my($arch_auto_dir, $arch_dir, $version_dir, $version_arch_dir)
	    = _get_dirs($path);
	++$names{$path};
	++$names{$arch_dir}         if -d $arch_auto_dir;
	++$names{$version_dir}      if -d $version_dir;
	++$names{$version_arch_dir} if -d $version_arch_dir;
    }

    # Remove ALL instances of each named directory.
    @INC = grep { !exists $names{$_} } @INC;
    return;
}

sub _get_dirs {
    my($dir) = @_;
    my($arch_auto_dir, $arch_dir, $version_dir, $version_arch_dir);

    $arch_auto_dir    = "$dir/$archname/auto";
    $arch_dir         = "$dir/$archname";
    $version_dir      = "$dir/$version";
    $version_arch_dir = "$dir/$version/$archname";

    return($arch_auto_dir, $arch_dir, $version_dir, $version_arch_dir);
}

1;
__END__



Upload File: 



    CMD: